DPaste - Paste #3025 - pastebin, online compiler and collaboration tool dedicated to D Programming Language

Pattern-matching in D

Code

module pattern;

import std.conv;
import std.typetuple;
import std.stdio;

class NoMatchException : Exception 
{
    this(string msg) { super(msg);}
}

struct Matcher(alias fun, size_t n, Rest...) /*if (n>1)*/ 
{
    TypeTuple!(Rest[0..n]) _m;

this(TypeTuple!(Rest[0..n]) m)
    {
        static if (n > 0)
            _m = m;
    }
    
	auto opCall() 
	{
        static if (is(typeof(fun(_m))))
            return fun(_m);
        else static if (n == 1 && is(typeof(fun(_m[0]))))
            return fun(_m[0]);
        else static if (Rest.length > n)
            return Matcher!(Rest[n], n, Rest[0..n], Rest[n+1..$])(_m)();
        else 
		{
            string s;
            foreach(i, Type; Rest[0..n]) s ~= to!string(_m[i]) ~ " ";
            throw new NoMatchException("No match for (" ~ s ~ ") of type " ~ typeof(_m).stringof);
        }
    }
}

template MatcherType(alias fun, size_t n, Rest...)
{
    static if (is(typeof(fun(Rest[0..n].init))))
        alias typeof(fun(Rest[0..n].init)) MatcherType;
    else static if (n == 1 && is(typeof(fun(Rest[0].init))))
        alias typeof(fun(Rest[0].init)) MatcherType;
    else static if (Rest.length > n)
        alias MatcherType!(Rest[n],n, Rest[0..n], Rest[n+1..$]) MatcherType;
    else
        static assert(false, "MatcherType: couldn't find a match for types " ~ Rest[0..n].stringof);
}

template match(alias fun, Rest...) 
{
    MatcherType!(fun, M.length, M, Rest) match(M...)(M m) 
	{
        return Matcher!(fun, M.length, M, Rest)(m)();
    }
}

string more(T...)(T t){ return "More than two args. Isn't life wonderful?";}

void main()
{
    alias match!(
        ()  => 3.14159,
        (a) => "One arg, of type " ~ typeof(a).stringof ~ " with value: " ~ to!string(a),
        (a, string b)=> "Two args (" ~ to!string(a) ~ ", " ~ to!string(b) ~ "). I know the second one is a string.",
        (a, b) => 0,
        more 
    ) matcher;

writeln(matcher());
    writeln(matcher(3.1416));
    writeln(matcher(1, "abc"));
    writeln(matcher(1, 1));
    writeln(matcher(1, "abc", 3.1416));
    writeln(matcher(1,1,1,1,1));
}

Application output:

3.14159
One arg, of type double with value: 3.1416
Two args (1, abc). I know the second one is a string.
0
More than two args. Isn't life wonderful?
More than two args. Isn't life wonderful?

Paste info

Author: Guest

Views: 87

Private: no

Expires: Never

Uploaded: 24.10.12 20:15

Votes: 0

Compilation

Compiler: DMD 2.060

Pointer size: m64

Code

Application output:

Paste info

Compilation

Actions

Confirm

Confirm