DPaste - Paste #2794 - pastebin, online compiler and collaboration tool dedicated to D Programming Language

Code

module program;

import std.stdio;

mixin template BankAccount () {
  public int amount;
  void deposit (int value) { this.amount += value; }
  void withdraw (int value) { this.amount -= value; }
  auto currentAmount () { return this.amount; }
}

mixin template Logger () {
  void deposit (int value) { writeln("User deposited money"); }
  void withdraw (int value) { writeln("User requested money back"); }
}

void main () {
  
  mixin aspect!("bank", BankAccount, Logger);
  
  bank b1;
  bank b2;
  
  b1.deposit(10);
  b1.deposit(20);
  b1.withdraw(5);
  writeln("b1.currentAmount: ", b1.currentAmount);

b2.deposit(50);
  b2.withdraw(40);
  b2.deposit(100);
  writeln("b2.currentAmount: ", b2.currentAmount);

}

// generic code

mixin template aspect (string name, T...) {
  template aspectDispatch (string name, uint n) {
    import convert = std.conv;
    static if (n >= 1)
      enum aspectDispatch = ""
        ~ "import std.traits;\n"
        ~ "static if (__traits(hasMember, data.aspect_" ~ convert.to!string(n) ~ ", `" ~ name ~ "`))\n"
        ~ "  static if (!is(ReturnType!(data.aspect_" ~ convert.to!string(n) ~ "." ~ name ~ ") == void))\n"
        ~ "    return data.aspect_" ~ convert.to!string(n) ~ "." ~ name ~ "(arguments);\n"
        ~ "  else\n"
        ~ "    data.aspect_" ~ convert.to!string(n) ~ "." ~ name ~ "(arguments);\n"
        ~ aspectDispatch!(name, n - 1)
      ;
    else
      enum aspectDispatch = "";
  }
  auto code () {
    import convert = std.conv;
    string ret = ""
      ~ "struct " ~ name ~ " {\n"
      ~ "  struct aspectData {\n"
    ;
    uint i = 0;
    foreach (a; T)
      ret ~= "    mixin " ~ __traits(identifier, a) ~ " aspect_" ~ convert.to!string(++i) ~ ";\n";
    ret ~= ""
      ~ "  }\n"
      ~ "  aspectData data;\n"
      ~ "  auto opDispatch (string fn, args...) (args arguments) {\n"
      ~ "    mixin(aspectDispatch!(fn, " ~ convert.to!string(i) ~ "));\n"
      ~ "  }\n"
      ~ "}\n"
    ;
    return ret;
  }
  mixin(code);
}

Application output:

User deposited money
User deposited money
User requested money back
b1.currentAmount: 25
User deposited money
User requested money back
User deposited money
b2.currentAmount: 110

Paste info

Author: Guest

Views: 105

Private: no

Expires: Never

Uploaded: 09.10.12 15:04

Votes: 0

Compilation

Compiler: DMD 2.060

Pointer size: m64

Code

Application output:

Paste info

Compilation

Actions

Confirm

Confirm