DPaste - Paste #875 - pastebin, online compiler and collaboration tool dedicated to D Programming Language

Variable interpolation in strings

Code

import std.string,
	std.regex;

/// Match a D identifier prefixed by a '$'
enum matchVars = `\$[_a-zA-Z][_a-zA-Z0-9]*`;

version(none)
{ 
/** 
 * Define a function to extract references to variables 
 *   into a comma-separated list like so:
 * "$foo $bar, $foo" -> "foo,bar,foo"
 * This is suitable for supplying as the value list to format().
 */
	enum ctMatchVars = ctRegex!(matchVars, "g");

// This is version(none) because the match() function isn't CTFE compatible
	string fetchVars(string fmt)
	{
		string ret = "";
		foreach (m; match(fmt, ctMatchVars))
			ret ~= m.hit[1..$] ~ ",";
		
		if (ret.length > 0)
			return ret[0..$-1];
		return ret;
	}

} else {
 	// a more painful version
	string fetchVars(string fmt)
	{
     	string ret = "";
		size_t pos = 0;

bool isIdentStart(char c)
		{
         	return c == '_' || 
				   (c >= 'A' && c <= 'Z') ||
				   (c >= 'a' && c <= 'z');
		}

bool isIdentChar(char c)
		{
         	return isIdentStart(c) ||
					(c >= '0' && c <= '9');
		}

while (pos < fmt.length)
		{
         	if (fmt[pos] == '$')
			{
				pos++;
				if (pos < fmt.length)
				{
                 	if (fmt[pos] == '{')
					{
                     	// consume until matching brace
						assert(false, "Complex expansion not yet supported");

} else if (isIdentStart(fmt[pos])) {
		             	// greedily consume identifier characters
						do
						{
                         	ret ~= fmt[pos];
						} while (++pos < fmt.length && isIdentChar(fmt[pos]));
						ret ~= ',';
					}
				} else
					break;
			} else
				pos++;
		}
		
		if (ret.length > 0)
			return ret[0..$-1];
		return ret;
	}
}

template Expand(string fmt)
{
	enum Expand = `format(std.regex.replace("`~fmt~`", regex(matchVars, "g"), "%s"), `~ 
						 fetchVars(fmt) ~ ")";
}
alias Expand x;

string inContext(string fmt, T)(T context)
{
 	with (context)
	{
     	return mixin(Expand!fmt);
	}
}

import std.stdio;
void main()
{
 	int foo = 10;
	double i = 1.9;
	writeln(mixin( Expand!("SELECT $foo, $i, $foo FROM thing") ));
	writeln(mixin( x!("SELECT $foo, $i, $foo FROM thing") ));

struct Ctx1
	{
     	bool tf;
		string name;
		double k;
	}
	auto ctx = Ctx1(true, "Anon", 2.1);
	writeln( ctx.inContext!("Some things for you: $tf and $name; also $$k dollars") );
}

Application output:

SELECT 10, 1.9, 10 FROM thing
SELECT 10, 1.9, 10 FROM thing
Some things for you: true and Anon; also $2.1 dollars

Paste info

Author: Guest

Views: 295

Private: no

Expires: Never

Uploaded: 26.07.12 20:34

Votes: 0

Compilation

Compiler: DMD 2.062

Pointer size: m64

Code

Application output:

Paste info

Compilation

Actions

Confirm

Confirm