DPaste - Paste #1132 - pastebin, online compiler and collaboration tool dedicated to D Programming Language

Function that switches between run-time and compile-time evaluation

Code

module main;

import std.stdio;
import core.time;

const answer = 42;

void main()
{
	with (TickDuration)
	{
		auto t0 = currSystemTick;

// a literal
		auto a = fib!78;
		writefln("Literal : fib(%s) == %s", 78, a);
		auto t1 = currSystemTick;

// a compile-time value (same algorith, but lightning fast)
		const k = 2uL * answer;
		auto b = fib!k;
		writefln("CT known: fib(%s) == %s", k, b);
		auto t2 = currSystemTick;

// a runtime value (slow)
		auto n = 38 + currSystemTick.length % 3;
		auto c = fib!(n);
		writefln("Runtime : fib(%s) == %s", n, c);
		auto t3 = currSystemTick;

writefln("Times: %s ms, %s ms, %s ms", (t1-t0).msecs, (t2-t1).msecs, (t3-t2).msecs);
	}
}

template fib(alias n)
{
	static if (__traits(compiles, __traits(parent, n)))
	{
		@property auto fibAlias() nothrow
		{
			typeof(n) fibRT(typeof(n) nRT) pure nothrow
			{
				if (nRT < 2) return nRT;
				return fibRT(nRT-1) + fibRT(nRT-2);
			}
			return fibRT(n);
		}
		alias fibAlias fib;
	}
	else
	{
		static if (n < 2) enum fib = n;
		else enum fib = fib!(n-1) + fib!(n-2);
	}
}

Application output:

Literal : fib(78) == 375819880
CT known: fib(84) == 160500643816367088
Runtime : fib(40) == 102334155
Times: 0 ms, 0 ms, 4393 ms

Paste info

Author: mleise

Views: 227

Private: no

Expires: Never

Uploaded: 07.08.12 19:42

Votes: 0

Compilation

Compiler: DMD 2.062

Pointer size: m64

Code

Application output:

Paste info

Compilation

Actions

Confirm

Confirm