DPaste - Paste #3358 - pastebin, online compiler and collaboration tool dedicated to D Programming Language

GetOpt with attributes

Code

import std.getopt, std.stdio, std.algorithm;

struct MyOptions
{
	[Option(["v", "verbose"])]
	bool verbose;
	
	[Option(["f", "file"], true)]
	string file;
	
	[Option(["n", "number"])]
	int n;
}

void main(string[] arguments)
{
	auto args = readArgs!MyOptions(arguments);
	
	writeln(args);
}

static T readArgs(T)(string[] args)
{
	T ret;
	pragma(msg, "getopt(args"~buildGetOptArguments!(T, "ret")~");");
	mixin("getopt(args"~buildGetOptArguments!(T, "ret")~");");
	
	return ret;
}

private static string buildGetOptArguments(T, string instanceName)()
{
	string s;
	foreach(m; __traits(allMembers, T))
	{	
		foreach(attr; __traits(getAttributes, __traits(getMember, T, m)))
		{
			static if(typeof(attr).stringof == "Option")
			{
				string tmp;
				
				/*if(attr.isRequired)
					tmp ~= "std.getopt.config.passThrough, ";
				else
					tmp ~= "std.getopt.config.noPassThrough, ";*/
					
				tmp ~= `"`;
				
				foreach(i, n; attr.names)
				{
					tmp ~= n;
					tmp ~= "|";
				}
				
				tmp = tmp[0..$-1];
				tmp ~= `" , `;
				tmp ~= "&"~instanceName~"."~m;
				
				s ~= ", " ~ tmp;
			}
		}
	}
	return s;
}

struct Option
{
	string[] names;
	bool isRequired;
	
	
	
	this(string[] n, bool r = false)
	{
		names = n;
		isRequired = r;
	}
	
	Option required()
	{
		isRequired = true;
		return this;
	}
}

Compilation output:

getopt(args, "v|verbose" , &ret.verbose, "f|file" , &ret.file, "n|number" , &ret.n);

Application output:

MyOptions(false, "abc.txt", 0)

Application arguments:

--file=abc.txt

Paste info

Author: robik

Views: 186

Private: no

Expires: Never

Uploaded: 12.11.12 17:53

Tags: attribute attributes

Votes: 0

Compilation

Compiler: DMD 2.x Gi

Pointer size: m64